Kevin's Blog
0%

操作系统真相还原CH2

发表于

为什么程序要载入内存

CPU 的硬件电路被设计成只能运行处于内存中的程序，这样做的原因，首先是内存比较快，且容量大。其次为了方式统一，类似接口，存储介质很多（硬盘，软盘，U盘），操作系统跟硬件不需要付出额外努力去支持。

什么是载入内存

  • 程序被加载器（软件或者硬件）加载到内存的某个区域
  • CPU的cs:ip寄存器被指向这个程序的起始地址

BIOS（基本输入输出系统，Base Input & Output System）

实模式下的1MB内存布局

Intel 8086有20条地址总线，可以访问1MB的内存空间，2的20次方。

0-0x9FFFF对应DRAM（动态随机访问内存：dynamic random access memory)，640kb；0xF0000-0xFFFFF对应的是ROM，里面存的是BIOS的代码，64kb；外设需要地址总线访问，提前预留一部分空间给外设、显存、硬盘控制器等，地址总线上的其余可用地址留给DRAM（我们眼中的物理内存）。

注：如果地址总线不够用，物理内存多大都没用。

BIOS由硬件加载，入口地址是0xFFFF0

CPU如何执行BIOS代码，即CPU中的cs：ip如何组合成0xFFFF0 ？

接电一瞬间，CPU的cs：ip寄存器被强制初始化为0xF000: 0xFFF0，由于开机时处于实模式，所以段基址要乘16，也就是左移4位，即1111 0000 0000 0000左移4位–>1111 0000 0000 0000 0000 为0xF0000+0xFFF0 = 0xFFFF0。此处是跳转指令 jmp far f000:e05b，跳向0xfe05b，这是BIOS代码真正执行的位置。

BIOS校验启动盘中位于0盘0道1扇区的内容

0盘0道1扇区本质上是0扇区（为什么为1，硬盘扇区表示法的CHS法），如果此扇区末尾两个字节分别是魔数0x55, 0xaa就认为此扇区存在可执行程序（主引导记录MBR），加载地址0x7c00（jmp 0:0x7c00）

MBR相关

MBR大小必须是512字节，为了保证两个魔数出现在末尾，即510字节、511字节处，并且bochs模拟的X86是小端字节序，所以最后两个字节是0xaa55，拆开就是0x55、0xaa。

NASM预留关键字$$$和$$$$

$表示本行代码前的标号，$$表示本section的起始地址，如果section用了vstart=xxxx修饰，$$就是此section的虚拟地址xxxx，$就是以xxxx为起始地址的顺延。如果没有定义section，nasm默认代码全部为一个section，起始地址为0。

NASM用法

nasm -f [-o ]

-o 用来指定输出可执行文件的名称，-f 用来指定输出可执行文件的格式，格式关注 bin 和 elf 格式，bin是默认输出格式，指纯二进制；elf是二进制可执行文件，里面掺杂了程序的内存布局，位置等信息，有一些与操作指令无关。

程序运行

1
2
进入root账户中的bochs-2.7文件夹
在命令行中输入 bochs -f bochsrc.disk

写入mbr.S

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
;主引导程序 
;------------------------------------------------------------
SECTION MBR vstart=0x7c00         
   mov ax,cs      
   mov ds,ax
   mov es,ax
   mov ss,ax
   mov fs,ax
   mov sp,0x7c00

; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06	   功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
   mov     ax, 0x600
   mov     bx, 0x700
   mov     cx, 0           ; 左上角: (0, 0)
   mov     dx, 0x184f	   ; 右下角: (80,25),
			   ; VGA文本模式中,一行只能容纳80个字符,共25行。
			   ; 下标从0开始,所以0x18=24,0x4f=79
   int     0x10            ; int 0x10

;;;;;;;;;    下面这三行代码是获取光标位置    ;;;;;;;;;
;.get_cursor获取当前光标位置,在光标位置处打印字符.
   mov ah, 3		; 输入: 3号子功能是获取光标位置,需要存入ah寄存器
   mov bh, 0		; bh寄存器存储的是待获取光标的页号

   int 0x10		; 输出: ch=光标开始行,cl=光标结束行
			; dh=光标所在行号,dl=光标所在列号

;;;;;;;;;    获取光标位置结束    ;;;;;;;;;;;;;;;;

;;;;;;;;;     打印字符串    ;;;;;;;;;;;
   ;还是用10h中断,不过这次是调用13号子功能打印字符串
   mov ax, message 
   mov bp, ax		; es:bp 为串首地址, es此时同cs一致，
			; 开头时已经为sreg初始化

   ; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
   mov cx, 5		; cx 为串长度,不包括结束符0的字符个数
   mov ax, 0x1301	; 子功能号13是显示字符及属性,要存入ah寄存器,
			; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
   mov bx, 0x2		; bh存储要显示的页号,此处是第0页,
			; bl中是字符属性, 属性黑底绿字(bl = 02h)
   int 0x10		; 执行BIOS 0x10 号中断
;;;;;;;;;      打字字符串结束	 ;;;;;;;;;;;;;;;

   jmp $		; 使程序悬停在此

   message db "1 MBR"
   times 510-($-$$) db 0
   db 0x55,0xaa

使用nasm编译

1
2
nasm -o mbr.bin mbr.S
ls -lb mbr.bin //查看是否是512字节

将mbr.bin写入硬盘中

1
2
3
4
5
dd if=/root/bochs-2.7/mbr.bin of=/root/bochs-2.7/hd60M.img bs=512 count=1 conv=notrunc //输入
输出：
记录了1+0 的读入
记录了1+0 的写出
512 bytes copied, 0.00617789 s, 82.9 kB/s

再次运行bochs

输出1 MBR

此章节结束